*  JieJie Microelectronics P-Spice Model Library
*  Filename	:   JMSH0406AGDQ_P v.20220923.txt
*  Product Name   :  JMSH0406AGDQ (PDFN5x6-8L-D)
*  Configuration:	: Dual N+N channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Sep 23, 2022
*  Junction Temp (Tj)	: -40C ~ 175C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH0406AGDQ D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
Vmonitor D 18 0
RD D 1 0.0006
RS S 3 1E-006
RG G 2 2.46
CGS 3 G 8.94e-10
EGD 12 0 2 1 1
Etemp 17 2 VALUE = {(-0.00389*(TEMP-25))+((-3.63468E-6)*(TEMP-25)^2)}
Gtemp 1 3  VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.7)}
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1.0E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
Cds D 3 Cbreak 1.1882E-9
.MODEL Cbreak CAP (C=1 VC1= -0.03849 VC2 = 4.66148E-4)

.model NMOS NMOS
+LEVEL = 3     
+VMAX = 1.0752E9               ETA = 1.21E-4  
+VTO = 2.923712                  TOX = 1.043684E-9             NSUB = 9.6E19  
+KP = 441.729059            U0 = 424                      KAPPA = 0.178        
+GAMMA = 6.22617E-2            PHI = 0.531402                THETA = 0.372738     
+ DELTA = 301.735647   

.model DCGD D
+CJO = 2.9E-10                 VJ = 13                       M = 1.1     
                   
.model DSUB D
+IS = 2.10904E-12              N = 1.029024                  RS = 2.50584E-3 
+BV = 45       
+xti = 2.403665      
+trs = 0             
.model DLIM D
+IS = 1E-4       
.ends JMSH0406AGDQ

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************






